03.12.25

21 files changed, 436 insertions, 0 deletions

diff --git a/config/nvim/after/queries/bash/highlights.scm b/config/nvim/after/queries/bash/highlights.scm
new file mode 100644
index 0000000..027baed
--- /dev/null
+++ b/config/nvim/after/queries/bash/highlights.scm
@@ -0,0 +1,8 @@
+;; vim: ft=query
+;; extends
+
+(function_definition
+  name: (word) @AlabasterDefinition)
+
+((program . (comment) @AlabasterHashbang)
+ (#match? @AlabasterHashbang "^#!/"))
diff --git a/config/nvim/after/queries/c/highlights.scm b/config/nvim/after/queries/c/highlights.scm
new file mode 100644
index 0000000..ddf4ab4
--- /dev/null
+++ b/config/nvim/after/queries/c/highlights.scm
@@ -0,0 +1,34 @@
+;; vim: ft=query
+;; extends
+
+(function_declarator
+  declarator: (identifier) @AlabasterDefinition)
+(preproc_function_def
+  name: (identifier) @AlabasterDefinition)
+
+(type_definition
+  type: (struct_specifier
+          name: (type_identifier) @AlabasterDefinition)
+  declarator: (type_identifier) @AlabasterDefinition)
+
+(type_definition
+  type: (struct_specifier)
+  declarator: (type_identifier) @AlabasterDefinition)
+
+(type_definition
+  type: (enum_specifier)
+  declarator: (type_identifier) @AlabasterDefinition)
+
+(struct_specifier
+  name: (type_identifier) @AlabasterDefinition)
+
+(declaration
+  type: (struct_specifier
+          name: (type_identifier) @AlabasterBase))
+
+(enum_specifier
+    name: (type_identifier) @AlabasterDefinition)
+
+(declaration
+  type: (enum_specifier
+          name: (type_identifier) @AlabasterBase))
diff --git a/config/nvim/after/queries/c_sharp/highlights.scm b/config/nvim/after/queries/c_sharp/highlights.scm
new file mode 100644
index 0000000..7658863
--- /dev/null
+++ b/config/nvim/after/queries/c_sharp/highlights.scm
@@ -0,0 +1,15 @@
+;; vim: ft=query
+;; extends
+
+(type_declaration
+  name: (identifier) @AlabasterDefinition)
+(constructor_declaration
+  name: (identifier) @AlabasterDefinition)
+(destructor_declaration
+  name: (identifier) @AlabasterDefinition)
+(method_declaration
+  name: (identifier) @AlabasterDefinition)
+(property_declaration
+  name: (identifier) @AlabasterDefinition)
+(namespace_declaration
+  name: (identifier) @AlabasterDefinition)
diff --git a/config/nvim/after/queries/clojure/highlights.scm b/config/nvim/after/queries/clojure/highlights.scm
new file mode 100644
index 0000000..3b586cd
--- /dev/null
+++ b/config/nvim/after/queries/clojure/highlights.scm
@@ -0,0 +1,32 @@
+;; extends
+(list_lit
+  value: (sym_lit) @_keyword.function
+  (#any-of? @_keyword.function "fn" "fn*" "defn" "defn-")
+  value: (sym_lit)? @AlabasterDefinition
+  value: (vec_lit)
+  (str_lit)? @comment)
+
+(list_lit
+  value: (sym_lit) @_keyword.function
+  (#any-of? @_keyword.function "fn" "fn*" "defn" "defn-")
+  value: (sym_lit)? @AlabasterDefinition
+  value: (list_lit))
+
+(list_lit
+  value: (sym_lit) @_keyword.function
+  (#eq? @_keyword.function "defmacro")
+  value: (sym_lit)? @AlabasterDefinition
+  value: (vec_lit)
+  (str_lit)? @comment)
+
+(list_lit
+  value: (sym_lit) @_include
+  (#eq? @_include "ns")
+  value: (sym_lit) @AlabasterDefinition)
+
+(list_lit
+  value: (kwd_lit) @AlabasterConstant)
+(vec_lit
+  value: (kwd_lit) @AlabasterConstant)
+(map_lit
+  value: (kwd_lit) @AlabasterConstant)
diff --git a/config/nvim/after/queries/commonlisp/highlights.scm b/config/nvim/after/queries/commonlisp/highlights.scm
new file mode 100644
index 0000000..0e83a9c
--- /dev/null
+++ b/config/nvim/after/queries/commonlisp/highlights.scm
@@ -0,0 +1,6 @@
+;; vim: ft=query
+;; extends
+
+(defun
+  (defun_header
+    function_name: (sym_lit) @AlabasterDefinition))
diff --git a/config/nvim/after/queries/cpp/highlights.scm b/config/nvim/after/queries/cpp/highlights.scm
new file mode 100644
index 0000000..db787e9
--- /dev/null
+++ b/config/nvim/after/queries/cpp/highlights.scm
@@ -0,0 +1,81 @@
+;; vim: ft=query
+;; extends
+
+(function_declarator
+  declarator: (qualified_identifier
+                name: (identifier) @AlabasterDefinition))
+
+;; TODO there's probably a lot of duplicates here
+
+(function_definition
+  declarator: (function_declarator
+                declarator: (destructor_name (identifier) @AlabasterDefinition)))
+
+(function_definition
+  declarator: (function_declarator
+                declarator: (field_identifier) @AlabasterDefinition))
+
+(function_definition
+  declarator: (function_declarator
+                declarator: (qualified_identifier
+                              name: (destructor_name
+                                      (identifier) @AlabasterDefinition))))
+
+(declaration
+  declarator: (function_declarator
+                declarator:
+                  (destructor_name (identifier) @AlabasterDefinition)))
+
+(field_declaration
+  declarator: (function_declarator
+                declarator: (field_identifier) @AlabasterDefinition))
+
+(field_declaration
+  declarator: (pointer_declarator
+                declarator: (function_declarator
+                              declarator:
+                                (field_identifier) @AlabasterDefinition)))
+
+(function_declarator
+ declarator: (field_identifier) @AlabasterDefinition)
+
+(function_declarator
+     declarator: (qualified_identifier
+                   name: (identifier) @AlabasterDefinition))
+(function_declarator
+     declarator: (qualified_identifier
+                   name: (qualified_identifier
+                           name: (identifier) @AlabasterDefinition)))
+((function_declarator
+     declarator: (qualified_identifier
+                   name: (identifier) @AlabasterDefinition))
+ (#lua-match? @AlabasterDefinition "^[A-Z]"))
+
+(labeled_statement
+  label: (statement_identifier) @AlabasterDefinition)
+
+(type_definition
+  declarator: (type_identifier) @AlabasterDefinition)
+
+(preproc_def
+  name: (identifier) @AlabasterDefinition)
+
+(class_specifier
+  name: (type_identifier) @AlabasterDefinition)
+
+(struct_specifier
+  name: (type_identifier) @AlabasterDefinition)
+
+(struct_specifier
+  name: (type_identifier) @AlabasterDefinition)
+
+(declaration
+  type: (struct_specifier
+          name: (type_identifier) @AlabasterBase))
+
+(enum_specifier
+    name: (type_identifier) @AlabasterDefinition)
+
+(declaration
+  type: (enum_specifier
+          name: (type_identifier) @AlabasterBase))
diff --git a/config/nvim/after/queries/fennel/highlights.scm b/config/nvim/after/queries/fennel/highlights.scm
new file mode 100644
index 0000000..c172336
--- /dev/null
+++ b/config/nvim/after/queries/fennel/highlights.scm
@@ -0,0 +1,23 @@
+;; vim: ft=query
+;; extends
+
+; (fn
+;   name: (symbol) @AlabasterDefinition)
+;   ; TODO: add this when https://github.com/nvim-treesitter/nvim-treesitter/issues/1788 is fixed
+;   ; docstring: (string)? @AlabasterComment
+; (fn
+;   name: (multi_symbol (symbol) @AlabasterDefinition))
+
+; (global
+;   (binding
+;     (symbol) @AlabasterDefinition))
+
+(list
+  (symbol) @function.macro
+  (#match? @function.macro "^macro$")
+  (symbol) @AlabasterDefinition)
+
+
+; ((program . (hashfn) @AlabasterHashbang)
+;  (#match? @AlabasterHashbang "^#!/")
+;  (#set! "priority" 101))
diff --git a/config/nvim/after/queries/fish/highlights.scm b/config/nvim/after/queries/fish/highlights.scm
new file mode 100644
index 0000000..d23c3b7
--- /dev/null
+++ b/config/nvim/after/queries/fish/highlights.scm
@@ -0,0 +1,16 @@
+;; vim: ft=query
+;; extends
+
+(function_definition
+  name: (word) @AlabasterDefinition)
+
+(command
+  name: (word) @function.builtin
+  (#match? @function.builtin "^set$")
+  argument: (word) @parameter
+  (#any-of? @parameter "-g" "--global" "-U" "--universal" "-x" "--export")
+  argument: (word) @AlabasterDefinition
+  argument: (_))
+
+((program . (comment) @AlabasterHashbang)
+ (#match? @AlabasterHashbang "^#!/"))
diff --git a/config/nvim/after/queries/go/highlights.scm b/config/nvim/after/queries/go/highlights.scm
new file mode 100644
index 0000000..d85f8bb
--- /dev/null
+++ b/config/nvim/after/queries/go/highlights.scm
@@ -0,0 +1,15 @@
+;; vim: ft=query
+;; extends
+
+(package_clause
+  (package_identifier) @AlabasterDefinition)
+
+(const_declaration
+  (const_spec
+    name: (identifier) @AlabasterDefinition))
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)
+
+(method_declaration
+  name: (field_identifier) @AlabasterDefinition)
diff --git a/config/nvim/after/queries/hare/highlights.scm b/config/nvim/after/queries/hare/highlights.scm
new file mode 100644
index 0000000..67514e2
--- /dev/null
+++ b/config/nvim/after/queries/hare/highlights.scm
@@ -0,0 +1,8 @@
+;; vim: ft=query
+;; extends
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)
+
+(type_declaration
+  (identifier) @AlabasterDefinition)
diff --git a/config/nvim/after/queries/java/highlights.scm b/config/nvim/after/queries/java/highlights.scm
new file mode 100644
index 0000000..f246f6e
--- /dev/null
+++ b/config/nvim/after/queries/java/highlights.scm
@@ -0,0 +1,11 @@
+;; vim: ft=query
+;; extends
+
+(class_declaration
+  name: (identifier) @AlabasterDefinition)
+(constructor_declaration
+  name: (identifier) @AlabasterDefinition)
+(method_declaration
+  name: (identifier) @AlabasterDefinition)
+(package_declaration
+  (scoped_identifier) @AlabasterDefinition)
diff --git a/config/nvim/after/queries/javascript/highlights.scm b/config/nvim/after/queries/javascript/highlights.scm
new file mode 100644
index 0000000..7f7749c
--- /dev/null
+++ b/config/nvim/after/queries/javascript/highlights.scm
@@ -0,0 +1,7 @@
+;; vim: ft=query
+;; extends
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)
+
+(undefined) @AlabasterConstant
diff --git a/config/nvim/after/queries/json/highlights.scm b/config/nvim/after/queries/json/highlights.scm
new file mode 100644
index 0000000..3f8ce97
--- /dev/null
+++ b/config/nvim/after/queries/json/highlights.scm
@@ -0,0 +1,6 @@
+;; vim: ft=query
+;; extends
+
+(object
+  (pair
+    key: (string) @AlabasterString))
diff --git a/config/nvim/after/queries/kotlin/highlights.scm b/config/nvim/after/queries/kotlin/highlights.scm
new file mode 100644
index 0000000..17d061d
--- /dev/null
+++ b/config/nvim/after/queries/kotlin/highlights.scm
@@ -0,0 +1,24 @@
+;; vim: ft=query
+;; extends
+(function_declaration
+  (simple_identifier) @AlabasterDefinition)
+
+(class_declaration
+  (type_identifier) @AlabasterDefinition)
+
+(object_declaration
+  (type_identifier) @AlabasterDefinition)
+
+(string_literal) @AlabasterString
+
+(boolean_literal) @AlabasterConstant
+(integer_literal) @AlabasterConstant
+(long_literal) @AlabasterConstant
+(unsigned_literal) @AlabasterConstant
+(real_literal) @AlabasterConstant
+
+(line_comment) @AlabasterHashbang
+(multiline_comment) @Comment
+
+
+(modifiers (annotation (user_type (type_identifier) @AlabasterPunctuation)))
diff --git a/config/nvim/after/queries/lua/highlights.scm b/config/nvim/after/queries/lua/highlights.scm
new file mode 100644
index 0000000..6f0e42d
--- /dev/null
+++ b/config/nvim/after/queries/lua/highlights.scm
@@ -0,0 +1,27 @@
+;; vim: ft=query
+;; extends
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)
+
+(assignment_statement
+  (variable_list
+    name: (dot_index_expression
+            field: (identifier) @AlabasterDefinition))
+  (expression_list
+    value: (function_definition)))
+
+(assignment_statement
+  (variable_list
+    name: (identifier) @AlabasterDefinition)
+  (expression_list
+    value: (function_definition)))
+
+(function_declaration
+  name: (dot_index_expression
+          field: (identifier) @AlabasterDefinition))
+
+(table_constructor
+  (field name: (identifier) @AlabasterString))
+
+(hash_bang_line) @AlabasterHashbang
diff --git a/config/nvim/after/queries/python/highlights.scm b/config/nvim/after/queries/python/highlights.scm
new file mode 100644
index 0000000..0d5ef66
--- /dev/null
+++ b/config/nvim/after/queries/python/highlights.scm
@@ -0,0 +1,13 @@
+;; vim: ft=query
+;; extends
+
+(function_definition
+  name: (identifier) @AlabasterDefinition)
+(class_definition
+  name: (identifier) @AlabasterDefinition)
+
+((module . (comment) @AlabasterHashbang)
+ (#match? @AlabasterHashbang "^#!/"))
+
+(decorator
+  (identifier) @AlabasterBase)
diff --git a/config/nvim/after/queries/rust/highlights.scm b/config/nvim/after/queries/rust/highlights.scm
new file mode 100644
index 0000000..b250310
--- /dev/null
+++ b/config/nvim/after/queries/rust/highlights.scm
@@ -0,0 +1,53 @@
+;; vim: ft=query
+;; extends
+
+(struct_item
+  name: (type_identifier) @AlabasterDefinition)
+(enum_item
+  name: (type_identifier) @AlabasterDefinition)
+
+(impl_item
+  type: (type_identifier) @AlabasterDefinition)
+
+(impl_item
+  type: (scoped_type_identifier
+          path: (scoped_identifier)
+          name: (type_identifier) @AlabasterDefinition))
+
+(impl_item
+  body: (declaration_list
+          (type_item
+            name: (type_identifier) @AlabasterDefinition)))
+(impl_item
+  type: (generic_type
+          type: (type_identifier) @AlabasterDefinition))
+
+(trait_item
+  name: (type_identifier) @AlabasterDefinition)
+
+(trait_item
+  body: (declaration_list
+          (associated_type
+            name: (type_identifier) @AlabasterDefinition)))
+
+(trait_item
+  body: (declaration_list
+          (function_signature_item
+            name: (identifier) @AlabasterDefinition)))
+
+(function_item
+  name: (identifier) @AlabasterDefinition)
+
+(macro_definition
+  name: (identifier) @AlabasterDefinition)
+
+(for_expression
+  "in" @AlabasterPunctuation)
+(type_arguments
+  "<" @AlabasterPunctuation)
+(type_arguments
+  ">" @AlabasterPunctuation)
+(type_parameters
+  "<" @AlabasterPunctuation)
+(type_parameters
+  ">" @AlabasterPunctuation)
diff --git a/config/nvim/after/queries/scala/highlights.scm b/config/nvim/after/queries/scala/highlights.scm
new file mode 100644
index 0000000..764e08b
--- /dev/null
+++ b/config/nvim/after/queries/scala/highlights.scm
@@ -0,0 +1,20 @@
+; vim: ft=query
+;; extends
+
+(package_clause
+  (package_identifier) @AlabasterDefinition)
+
+(function_definition
+  name: (identifier) @AlabasterDefinition)
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)
+
+(class_definition
+  name: (identifier) @AlabasterDefinition)
+
+(object_definition
+  name: (identifier) @AlabasterDefinition)
+
+(trait_definition
+  name: (identifier) @AlabasterDefinition)
diff --git a/config/nvim/after/queries/typescript/highlights.scm b/config/nvim/after/queries/typescript/highlights.scm
new file mode 100644
index 0000000..b3cfa8d
--- /dev/null
+++ b/config/nvim/after/queries/typescript/highlights.scm
@@ -0,0 +1,20 @@
+;; vim: ft=query
+;; extends
+
+(interface_declaration
+  name: (type_identifier) @AlabasterDefinition)
+
+(method_definition
+  name: (property_identifier) @AlabasterDefinition)
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)
+
+(variable_declarator
+  name: (identifier) @AlabasterDefinition
+  value: (arrow_function))
+
+(type_alias_declaration
+  name: (type_identifier) @AlabasterDefinition)
+
+(undefined) @AlabasterConstant
diff --git a/config/nvim/after/queries/vim/highlights.scm b/config/nvim/after/queries/vim/highlights.scm
new file mode 100644
index 0000000..f11905d
--- /dev/null
+++ b/config/nvim/after/queries/vim/highlights.scm
@@ -0,0 +1,12 @@
+;; vim: ft=query
+;; extends
+
+(function_definition
+  (function_declaration
+    name: (scoped_identifier
+            (scope)
+            (identifier) @AlabasterDefinition)))
+
+(function_definition
+  (function_declaration
+    name: (identifier) @AlabasterDefinition))
diff --git a/config/nvim/after/queries/zig/highlights.scm b/config/nvim/after/queries/zig/highlights.scm
new file mode 100644
index 0000000..3b79bef
--- /dev/null
+++ b/config/nvim/after/queries/zig/highlights.scm
@@ -0,0 +1,5 @@
+;; vim: ft=query
+;; extends
+
+(function_declaration
+  name: (identifier) @AlabasterDefinition)